OpenFlexure Microscope OpenSCAD docs

function tiny() = 0.05;

function zero_z(size) = [size.x, size.y, 0];

function if_undefined_set_default(argument, default) = is_undef(argument) ? default : argument;

module translate_x(x_tr){
    translate([x_tr, 0, 0]){
        children();
    }
}

module translate_y(y_tr){
    translate([0, y_tr, 0]){
        children();
    }
}

module translate_z(z_tr){
    translate([0, 0, z_tr]){
        children();
    }
}

module rotate_x(x_angle){
    rotate([x_angle, 0, 0]){
        children();
    }
}

module rotate_y(y_angle){
    rotate([0, y_angle, 0]){
        children();
    }
}

module rotate_z(z_angle){
    rotate([0, 0, z_angle]){
        children();
    }
}

module reflect(axis){
    children();
    mirror(axis){
        children();
    }
}

module reflect_x(){
    reflect([1, 0, 0]){
        children();
    }
}

module reflect_y(){
    reflect([0, 1, 0]){
        children();
    }
}

module reflect_z(){
    reflect([0, 0, 1]){
        children();
    }
}

function vector_mirror_x(vec) = _vector_mirror_axis(vec, 0);

function vector_mirror_y(vec) = _vector_mirror_axis(vec, 1);

function vector_mirror_z(vec) = _vector_mirror_axis(vec, 2);

function _vector_mirror_axis(vec, axis_index) = [
    for (i = [0:len(vec)-1])
        if (i==axis_index)
            -vec[i]
        else
            vec[i]
];

module repeat(delta, N, center=false){
    //repeat children along a regular array
    center_tr = (center ?  -(N-1)/2 : 0) * delta;
    translate(center_tr){
        for(i=[0:1:(N-1)]){
            translate(i*delta){
                children();
            }
        }
    }
}

module xz_slice(y=0){
    intersection(){
        translate_y(y){
            cube([999,2*tiny(),999],center=true);
        }
        children();
    }
}

module tube(ri, ro, h, center=false){
    difference(){
        cylinder(r=ro, h=h, center=center);
        if (center){
            cylinder(r=ri, h=h+1, center=true);
        }
        else {
            translate_z(-1){
                cylinder(r=ri, h=h+2, center=false);
            }
        }
    }
}

module m4_selftap_hole(h=10, center=false){
    // r and flat calculated from the trylinder selftap function used for years.
    // Moving to explicit tested number rather than arbitrary calculations.
    trylinder(r=1.3, flat=1.73, h=h, center=center);
}

module no2_selftap_hole(h=10, center=false){
    //This value for r came from test prints. ranging r from 0.3 to 0.5.
    trylinder(r=.3, flat=1.73, h=h, center=center);
}

module no2_selftap_clearancehole(h=10, center=false){
    cylinder(d=2.5, h=h, center=center);
}

module no2_selftap_counterbore(bore_h=999, hole_h=999, flip_z=false, tight=false){
    $fn = 14;
    bore_d = tight ? 4.8 : 5.6;
    generic_counterbore(bore_d=bore_d, bore_h=bore_h, hole_d=2.5, hole_h=hole_h, flip_z=flip_z);
}

module no1_selftap_hole(h=10, center=false){
    //This value for flat came from scaling the No2 hole.
    trylinder(r=.3, flat=1.23, h=h, center=center);
}

module m3_cap_counterbore(bore_h=999, hole_h=999, flip_z=false){
    $fn = 14;
    generic_counterbore(bore_d=6.5, bore_h=bore_h, hole_d=3.5, hole_h=hole_h, flip_z=flip_z);
}

module generic_counterbore(bore_d, bore_h, hole_d, hole_h, flip_z=false){
    if (flip_z){
        intersection(){
            hole_from_bottom(r=hole_d/2, h=hole_h, base_w=bore_d*2, big_bottom=false);
            cylinder(d=bore_d, h=3*hole_h, center=true);
        }
        translate_z(-(bore_h-tiny())){
            cylinder(d=bore_d, h=bore_h+tiny());
        }
    }
    else{
        translate_z(-hole_h){
            cylinder(d=hole_d, h=hole_h+tiny());
        }
        cylinder(d=bore_d, h=bore_h);
    }
}

module m3_nut_hole(h=undef,center=false, tight=false ,shaft=false){

    // Note 2.6mm is the standard height giving 0.2mm clearance over the maximum
    // m3 nut height (2.4mm) as specified in ISO 4032
    height = if_undefined_set_default(h, 2.6);

    // According too ISO 4032 maximum flat-to-flat distance of an m3 nut is
    // 5.5mm (minimum is 5.32mm). As the corners are rounder the minimum width
    // across corners is specified as 6.01mm.
    //
    // As 3D printers slightly undersize small holes 5.7mm is chosen as the standard
    // nut trap width. giving 0.2mm clearance and still 0.31mm interference.
    //
    // Tight traps are 0.1mm smaller. They are used in locations where it is easy
    // to pull the nut (or hex bolt head) into the trap (such as on the gears)
    width = tight ? 5.6 : 5.7;

    // diameter of  circumcribed circule
    trap_diameter = width/sin(60);

    // clearance factor determined empirically over many years
    shaft_diameter = 3*1.16;

    union(){
        cylinder(d=trap_diameter, h=height, center=center, $fn=6);
        if(shaft){
            cylinder(d=shaft_diameter, h=999, center=true, $fn=16);
        }
    }
}

module m3_nut_hole_y(h=undef, center=false, extra_height=0.1, shaft_length=0, nut_angle=0){
    
    // See module `m3_nut_hole` for explanation of these sizes
    height = if_undefined_set_default(h, 2.6);
    width = 5.7;
    // diameter of  circumcribed circule
    trap_diameter = width/sin(60);
    // clearance factor determined empirically over many years
    shaft_diameter = 3*1.16;

    union(){
        rotate([-90, 0, 0]){
            rotate_z(nut_angle){
                cylinder(d=trap_diameter, h=height, center=center, $fn=6);
            }
        }

        if(shaft_length > 0){
            translate_y(height/2){
                printable_horizontal_hole(h=2*shaft_length,
                                          r=shaft_diameter/2,
                                          extra_height=extra_height,
                                          center=true,
                                          $fn=16);
            }
        }

        if (nut_angle==0){
            // extra space on top of nut, only makes sense if the nut is flat down/up
            center_y = center ? -height/2 : 0;

            //Note: The cirumscribed radius of a hexagon is the same as the face length.
            translate([-trap_diameter/4, center_y ,0]){
                cube([trap_diameter/2, height, width/2+extra_height]);
            }
        }
    }
}

module cyl_slot(r=1, h=1, dy=2, center=false){

    hull(){
        repeat([0, dy, 0], 2, center=true){
            cylinder(r=r, h=h, center=center);
        }
    }
}

module keyhole(h, r_hole, r_slot, l_slot, center=false){
    translate_y(l_slot/2){
        cyl_slot(r=r_slot, h=h, dy=l_slot, center=center);
    }
    cylinder(r=r_hole, h=h, center=center);
}

module unrotate(rotation){
    //undo a previous rotation
    //Note: this is not the same as rotate(-rotation) due to ordering.
    rotate_x(-rotation.x){
        rotate_y(-rotation.y){
            rotate_z(-rotation.z){
                children();
            }
        }
    }
}

module sparse_matrix_transform(xx=1, yy=1, zz=1, xy=0, xz=0, yx=0, yz=0, zx=0, zy=0, xt=0, yt=0, zt=0){
    //Apply a matrix transformation, specifying the matrix sparsely
    //This is useful because most helpful matrices are close to the identity.
    matrix = [[xx, xy, xz, xt],
              [yx, yy, yz, yt],
              [zx, zy, zz, zt],
              [0,  0,  0,  1]];
    multmatrix(matrix){
        children();
    }
}

module sequential_hull(){
    //given a sequence of >2 children, take the convex hull between each pair - a helpful, general extrusion technique.
    for(i=[0:$children-2]){
        hull(){
            children(i);
            children(i+1);
        }
    }
}

module convex_fillet(r){
    offset(r){
        offset(-r){
            children();
        }
    }
}

module concave_fillet(r){
    offset(-r){
        offset(r){
            children();
        }
    }
}

module thick_section(h=tiny(), center=false, shift=true){
    offset_thick_section(h=h, center=center, shift=shift){
        children();
    }
}

module offset_thick_section(h=tiny(), offset=0, center=false, shift=true){
    linear_extrude(h, center=center){
        offset(r=offset){
            flatten(shift){
		children();
            }
        }
    }
}

module printable_horizontal_hole(h,r,center=false,extra_height=0.7){
    top_block_dims = [2*sin(45/2)*r, 2*tiny(), h];
    top_block_z = center ? 0 : h/2;
    top_block_tr = [0, r-tiny(), top_block_z];
    union(){
        rotate([90,0,180]){
            hull(){
                cylinder(h=h,r=r,center=center);
                translate(top_block_tr){
                    cube(top_block_dims, center=true);
                }
            }
            translate(top_block_tr){
                cube(top_block_dims + [0, 2*extra_height, 0], center=true);
            }
        }
    }
}

module square_to_circle(r, h, layers=4, top_cylinder=0){
    // A stack of thin shapes, starting as a square and
    // gradually gaining sides to turn into a cylinder
    sides=[4,8,16,32,64,128,256]; //number of sides
    for(i=[0:(layers-1)]){
        rotate(180/sides[i]){
            translate_z(i*h/layers){
                cylinder(r=r/cos(180/sides[i]),h=h/layers+tiny(),$fn=sides[i]);
            }
        }
    }

    if(top_cylinder>0){
        translate_z(tiny()){
            cylinder(r=r,h=h+top_cylinder, $fn=sides[layers-1]);
        }
    }
}

module hole_from_bottom(r, h, base_w=-1, delta_z=0.5, layers=4, big_bottom=true){

    base = base_w>0 ? [base_w,2*r,2*delta_z] : [2*r,2*r,tiny()];
    union(){
        cube(base,center=true);
        translate_z(base.z/2-tiny()){
            square_to_circle(r, delta_z*4, layers, h-delta_z*5+tiny());
        }
        if(big_bottom){
            mirror([0,0,1]){
                cylinder(r=999,h=999,$fn=8);
            }
        }
    }
}

function determine_number_of_fragments(r) = let(
    n_points_from_fa = ceil(360/$fa),
    n_points_from_fs = ceil(r*2*PI/$fs),
    default_n_points = max(min(n_points_from_fa, n_points_from_fs),5), // use minimum size or maximum angle
    n_points = max($fn>0?$fn:default_n_points, 3) // $fn takes precedence, with minimum of 3
) n_points;

module trylinder(r=1, flat=1, h=tiny(), center=false){
    hull(){
        for(a=[0,120,240]){
            rotate(a){
                translate_y(flat/sqrt(3)){
                    cylinder(r=r, h=h, center=center);
                }
            }
        }
    }
}

module trylinder_selftap(nominal_d=3, h=10, center=false){
    // Make a trylinder that you can self-tap a machine screw into.
    // The size is deliberately a bit big for small holes, so that
    // it compensates for splodgy printing
    echo("Warning: `trylinder_selftap` is no longer recommended for use.");
    echo("Use explicitly defined holes such as `m4_selftap_hole` for screw sizes M4 and above.");
    echo("Use explicit holes for self tap screws, such as `no2_selftap_hole`");
    echo("For machine screws smaller than M4 use nut traps to avoid thread stripping.");
    r = max(nominal_d*0.8/2 + 0.2, nominal_d/2 - 0.2);
    dr = 0.5;
    flat = dr * 2 * sqrt(3);
    trylinder(r=r - dr, flat=flat, h=h, center=center);
}

module trylinder_gripper(inner_r=10,h=6,grip_h=3.5,base_r=-1,t=0.65,squeeze=1,flare=0.8,solid=false){
    $fn=48;
    bottom_r=base_r>0?base_r:inner_r+1+t;

    //TODO: reduce repition
    difference(){
        sequential_hull(){
            cylinder(r=bottom_r,h=tiny());
            translate_z(grip_h-0.5){
                trylinder(r=inner_r-squeeze+t,flat=2.5*squeeze,h=tiny());
            }
            translate_z(grip_h+0.5){
                trylinder(r=inner_r-squeeze+t,flat=2.5*squeeze,h=tiny());
            }
            translate_z(h-tiny()){
                trylinder(r=inner_r-squeeze+flare+t,flat=2.5*squeeze,h=tiny());
            }
        }
        if(solid==false){
            sequential_hull(){
                translate_z(-tiny()){
                    cylinder(r=bottom_r-t,h=tiny());
                }
                translate_z(grip_h-0.5){
                    trylinder(r=inner_r-squeeze,flat=2.5*squeeze,h=tiny());
                }
                translate_z(grip_h+0.5){
                    trylinder(r=inner_r-squeeze,flat=2.5*squeeze,h=tiny());
                }
                translate_z(h){
                    trylinder(r=inner_r-squeeze+flare,flat=2.5*squeeze,h=tiny());
                }
            }
        }
    }
}

module deformable_hole_trylinder(r1, r2, h=99, corner_roc=undef, delta_z=0.5, center=false){
    n = floor(h/(2*delta_z)); //number of layers in the structure
    flat_l = 2*sqrt(r2*r2 - r1*r1);
    default_corner_radius = r1 - flat_l/(2*sqrt(3));
    corner_radius = if_undefined_set_default(corner_roc, default_corner_radius);
    repeat([0,0,2*delta_z], n, center=center){
        union(){
            cylinder(r=r2, h=delta_z+tiny());
            translate_z(center ? -delta_z : delta_z){
                trylinder(r=corner_radius, flat=flat_l, h=delta_z+tiny());
            }
        }
    }
}

module exterior_brim(r=4, h=0.2, brim_only=false, smooth_r=undef){
    // Add a "brim" around the outside of an object *only*, preserving holes in the object
    // brim width r and the smoothing smooth_r can be defined separately, but default to equal

    _smooth_r = is_undef(smooth_r) ? r : smooth_r;

    if (!brim_only){
        children();
    }

    if(r > 0){
        linear_extrude(h){
            difference(){
                offset(r){
                    offset(-_smooth_r){
                        offset(_smooth_r){
                            flatten(){
                                children();
                            }
                        }
                    }
                }
                offset(-_smooth_r+tiny()){
                    offset(_smooth_r){
                        flatten(){
                            children();
                        }
                    }
                }
            }
        }
    }
}

module fillet_2d(r=3)
{
    convex_fillet(r=r){
        concave_fillet(r=r){
            children();
        }
    }
}

module cylinder_to_square_column(d=undef, r=undef, h=undef, transition=undef){
    _r = if_undefined_set_default(r, 0.5);
    _d = if_undefined_set_default(d, 2*_r);
    _h = if_undefined_set_default(h, 1);
    _transition = if_undefined_set_default(transition, _h-0.01);
    assert(_transition<_h,"Transition length must be shorter than the column height");
    _thin = _h - _transition ;
    hull(){
        cylinder(d=_d,h=_thin);
        translate([-_d/2,-_d/2,_h-_thin]){
            cube([_d,_d,_thin]);
        }
    }
}

module round_top_cube(dimensions, rounding_radius, center=false){
    corner_x = dimensions.x/2 - rounding_radius;
    corner_y = dimensions.y/2 - rounding_radius;
    height = dimensions.z - rounding_radius;
    corners = [
        [corner_x, corner_y, 0],
        [-corner_x, corner_y, 0],
        [corner_x, -corner_y, 0],
        [-corner_x, -corner_y, 0]
    ];
    trans = (center)? [0,0,0] : [dimensions.x/2, dimensions.y/2, 0];
    translate(trans){
        hull(){
            for (i = [0:3]){
                translate(corners[i]){
                    cylinder(r=rounding_radius, h=height);
                    translate_z(height){
                        sphere(r=rounding_radius);
                    }
                }
            }
        }
    }
}

module flatten(shift=true){
    projection(cut=true){
        translate_z(shift ? -tiny() : 0){
            children();
        }
    }
}